♻️ [shared] Moved Hm configs to shared base

shared/base/home-manager/default.nix

@@ -1,3 +1,12 @@
+{ inputs, ... }:
+
 {
-  imports = [ ./ssh.nix ];
+  imports = [
+    inputs.catppuccin.homeModules.catppuccin
+    ./development
+    ./shell
+    ./gpg.nix
+    ./home-manager.nix
+    ./ssh.nix
+  ];
 }

shared/base/home-manager/development/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./git.nix
+    ./helix.nix
+  ];
+}

shared/base/home-manager/development/git.nix

@@ -0,0 +1,35 @@
+{ pkgs, common, ... }:
+
+{
+  home.packages = with pkgs; [
+    git-crypt
+    gitmoji-cli
+  ];
+
+  programs.git =
+    let
+      package = pkgs.git.override { withLibsecret = true; };
+    in
+    {
+      enable = true;
+      package = package;
+      userName = "Martin Berg Alstad";
+      userEmail = "git@${common.domain}";
+
+      aliases = {
+        amend = "commit --amend";
+        cm = "commit";
+        s = "status";
+        p = "push";
+      };
+
+      signing.signByDefault = true;
+
+      extraConfig = {
+        pull.rebase = true;
+        push.autoSetupRemote = true;
+        safe.directory = "/etc/nixos";
+        credential.helper = "${package}/bin/git-credential-libsecret";
+      };
+    };
+}

shared/base/home-manager/development/helix.nix

@@ -0,0 +1,103 @@
+{
+  pkgs,
+  lib,
+  theme,
+  ...
+}:
+
+{
+  catppuccin.helix = {
+    enable = true;
+    flavor = theme.flavor;
+  };
+
+  programs = {
+    fish.shellAliases.edit = "hx";
+    helix =
+      let
+        prettier = format: {
+          command = "prettier";
+          args = [
+            "--stdin-filepath"
+            "file.${format}"
+          ];
+        };
+      in
+      {
+        enable = true;
+        defaultEditor = true;
+        extraPackages = with pkgs; [
+          # Markdown
+          marksman
+          markdown-oxide
+          # Html, css, Json, Eslint
+          vscode-langservers-extracted
+          # Yaml
+          ansible-language-server
+          yaml-language-server
+        ];
+        settings = {
+          editor = {
+            auto-save = {
+              after-delay.enable = true;
+              focus-lost = true;
+            };
+            cursor-shape = {
+              normal = "block";
+              insert = "bar";
+              select = "underline";
+            };
+            lsp = {
+              display-inlay-hints = true;
+              display-messages = true;
+            };
+          };
+          keys.normal = {
+            C-f = ":format";
+          };
+        };
+
+        languages.language = [
+          {
+            name = "css";
+            formatter = prettier "css";
+            auto-format = true;
+          }
+          {
+            name = "json";
+            language-servers = [
+              "vscode-json-language-server"
+            ];
+            formatter = prettier "json";
+            auto-format = true;
+          }
+          {
+            name = "jsonc";
+            language-servers = [
+            ];
+            formatter = prettier "jsonc";
+            file-types = [
+              "jsonc"
+            ];
+            auto-format = true;
+          }
+          {
+            name = "markdown";
+            formatter = prettier "md";
+            auto-format = true;
+          }
+          {
+            name = "nix";
+            formatter.command = lib.getExe pkgs.nixfmt-rfc-style;
+            auto-format = true;
+          }
+          {
+            name = "yaml";
+            formatter = prettier "yaml";
+            auto-format = true;
+          }
+        ];
+
+      };
+  };
+}

shared/base/home-manager/gpg.nix

@@ -0,0 +1,10 @@
+{ pkgs, ... }:
+
+{
+  programs.gpg.enable = true;
+  services.gpg-agent = {
+    enable = true;
+    enableFishIntegration = true;
+    pinentryPackage = pkgs.pinentry-curses;
+  };
+}

shared/base/home-manager/home-manager.nix

@@ -0,0 +1,20 @@
+{
+  outputs,
+  systemConfig,
+  common,
+  ...
+}:
+
+{
+  home = {
+    username = systemConfig.username;
+    homeDirectory = common.dir.home;
+    stateVersion = systemConfig.version;
+  };
+
+  # Adds pkgs.unstable in order to fetch packages from unstable repositories
+  nixpkgs.overlays = [ outputs.overlays.unstable-packages ];
+
+  # Let Home Manager install and manage itself.
+  programs.home-manager.enable = true;
+}

shared/base/home-manager/shell/btop.nix

@@ -0,0 +1,10 @@
+{ theme, ... }:
+
+{
+  catppuccin.btop = {
+    enable = true;
+    flavor = theme.flavor;
+  };
+
+  programs.btop.enable = true;
+}

shared/base/home-manager/shell/default.nix

@@ -0,0 +1,10 @@
+{
+  imports = [
+    ./btop.nix
+    ./eza.nix
+    ./fastfetch.nix
+    ./fish.nix
+    ./fzf.nix
+    ./zoxide.nix
+  ];
+}

shared/base/home-manager/shell/eza.nix

@@ -0,0 +1,12 @@
+{
+  programs = {
+    eza = {
+      enable = true;
+      colors = "always";
+      enableFishIntegration = true;
+      git = true;
+      icons = "always";
+    };
+    fish.shellAliases.ls = "eza";
+  };
+}

shared/base/home-manager/shell/fastfetch.nix

@@ -0,0 +1,63 @@
+{ lib, ... }:
+
+{
+  programs = {
+    fish.shellAliases.fetch = "fastfetch";
+
+    fastfetch = {
+      enable = true;
+      settings = {
+        logo = {
+          source = "${lib.custom.relativeToRoot "shared/assets/Catppuccin.png"}";
+          type = "kitty";
+          height = 18;
+          padding.top = 2;
+        };
+        display.separator = " ";
+        modules =
+          let
+            keyColor = "34";
+            module = type: key: {
+              inherit type key keyColor;
+            };
+            formatModule = type: key: format: {
+              inherit
+                type
+                key
+                format
+                keyColor
+                ;
+            };
+          in
+          [
+            "break"
+            "break"
+            {
+              type = "title";
+              keyWidth = 10;
+            }
+            "break"
+            (module "os" " ")
+            (module "kernel" " ")
+            (formatModule "packages" " " "{} (nixpkgs)")
+            (module "shell" " ")
+            (module "terminal" " ")
+            (module "wm" " ")
+            (module "theme" " ")
+            (module "cursor" " ")
+            (module "terminalfont" " ")
+            (module "uptime" " ")
+            (formatModule "datetime" " " "{1}-{3}-{11}")
+            (module "cpu" " ")
+            (module "gpu" "󰤽 ")
+            (module "sound" " ")
+            (module "lm" " ")
+            "break"
+            "colors"
+            "break"
+            "break"
+          ];
+      };
+    };
+  };
+}

shared/base/home-manager/shell/fish.nix

@@ -0,0 +1,55 @@
+{ pkgs, theme, ... }:
+
+{
+  catppuccin = {
+    fish = {
+      enable = true;
+      flavor = theme.flavor;
+    };
+    starship = {
+      enable = true;
+      flavor = theme.flavor;
+    };
+  };
+
+  programs = {
+    fish = {
+      enable = true;
+      # Start starship when creating a new shell
+      interactiveShellInit = ''
+        starship init fish | source
+        ${pkgs.fortune}/bin/fortune | ${pkgs.cowsay}/bin/cowsay -f tux
+      '';
+      plugins = [
+        {
+          # !! to get the previous command
+          # https://github.com/BrewingWeasel/fishbang
+          name = "fishbang";
+          src = pkgs.fetchFromGitHub {
+            owner = "BrewingWeasel";
+            repo = "fishbang";
+            rev = "50389667eb9ac79edcff9b987c83e1de8ac93921";
+            hash = "sha256-IneNWyfo29C7FDA5b6pTZRX3HpP6y/dRM6GXuLq2+zc=";
+          };
+        }
+      ];
+      shellAliases = {
+        nix-shell = "nix-shell --run fish"; # Start nix-shells using fish
+      };
+    };
+
+    starship = {
+      enable = true;
+      settings = {
+        directory.substitutions = {
+          "Documents" = "󰈙 ";
+          "Downloads" = " ";
+          "Music" = "󰓃 ";
+          "Pictures" = " ";
+          "Git" = " ";
+          "nextcloud" = " ";
+        };
+      };
+    };
+  };
+}

shared/base/home-manager/shell/fzf.nix

@@ -0,0 +1,13 @@
+{ theme, ... }:
+
+{
+  catppuccin.fzf = {
+    enable = true;
+    flavor = theme.flavor;
+  };
+
+  programs.fzf = {
+    enable = true;
+    enableFishIntegration = true;
+  };
+}

shared/base/home-manager/shell/zoxide.nix

@@ -0,0 +1,10 @@
+# cd alternative
+{
+  programs = {
+    fish.shellAliases.cd = "z";
+    zoxide = {
+      enable = true;
+      enableFishIntegration = true;
+    };
+  };
+}