✨ Moved modeules into shared

shared/modules/default.nix

@@ -0,0 +1,17 @@
+{
+  imports = [
+    ./development
+    ./fonts.nix
+    ./gaming
+    ./gnome
+    ./hardware
+    ./locale.nix
+    ./networking.nix
+    ./nix-helper.nix
+    ./hyprland
+    ./sddm.nix
+    ./security.nix
+    ./shell.nix
+    ./qt.nix
+  ];
+}

shared/modules/development/default.nix

@@ -0,0 +1,24 @@
+{ pkgs, ... }:
+
+{
+  imports = [
+    ./docker.nix
+    ./dotnet.nix
+    ./nix.nix
+    ./node.nix
+    ./ollama.nix
+    ./rust.nix
+  ];
+
+  environment.systemPackages = with pkgs; [
+    # IDEs
+    vscodium # TODO set up extensions
+    # Tools
+    git
+    just
+    unstable.libpq # Required for PostgreSQL
+    # Formatters
+    treefmt
+    shfmt
+  ];
+}

shared/modules/development/docker.nix

@@ -0,0 +1,10 @@
+{
+  virtualisation.docker = {
+    enable = true;
+    storageDriver = "btrfs";
+    rootless = {
+      enable = true;
+      setSocketVariable = true;
+    };
+  };
+}

shared/modules/development/dotnet.nix

@@ -0,0 +1,9 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    jetbrains.rider
+    dotnet-sdk_9
+    dotnet-aspnetcore_9
+  ];
+}

shared/modules/development/nix.nix

@@ -0,0 +1,11 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    # Language servers
+    nixd
+    nil
+    # Formatters
+    nixfmt-rfc-style
+  ];
+}

shared/modules/development/node.nix

@@ -0,0 +1,10 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    jetbrains.webstorm
+    nodejs_22
+    pnpm
+    nodePackages.prettier
+  ];
+}

shared/modules/development/ollama.nix

@@ -0,0 +1,6 @@
+{
+  services.ollama = {
+    enable = true;
+    acceleration = "cuda";
+  };
+}

shared/modules/development/rust.nix

@@ -0,0 +1,17 @@
+{ pkgs, ... }:
+
+{
+  environment = {
+    sessionVariables = {
+      # Required for some Rust dependencies, like reqwest
+      PKG_CONFIG_PATH = "${pkgs.openssl.dev}/lib/pkgconfig";
+    };
+
+    systemPackages = with pkgs; [
+      jetbrains.rust-rover
+      rustup
+      gcc
+      pkg-config # Required for some Rust dependencies
+    ];
+  };
+}

shared/modules/fonts.nix

@@ -0,0 +1,19 @@
+{ pkgs, theme, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    font-awesome # Icons
+  ];
+
+  fonts = {
+    fontconfig.enable = true;
+    packages = with pkgs; [
+      (nerdfonts.override { fonts = [ theme.nerdFont ]; })
+      jetbrains-mono
+      # The line below will replace the lines above in 25.05
+      # nerd-fonts.jetbrains-mono
+      font-awesome
+    ];
+  };
+
+}

shared/modules/gaming/default.nix

@@ -0,0 +1,12 @@
+{ pkgs, ... }:
+
+{
+  imports = [
+    ./steam.nix
+  ];
+
+  environment.systemPackages = with pkgs; [
+    heroic
+    wine
+  ];
+}

shared/modules/gaming/steam.nix

@@ -0,0 +1,8 @@
+{
+  programs.steam = {
+    enable = true;
+    remotePlay.openFirewall = true; # Open ports in the firewall for Steam Remote Play
+    dedicatedServer.openFirewall = true; # Open ports in the firewall for Source Dedicated Server
+    localNetworkGameTransfers.openFirewall = true; # Open ports in the firewall for Steam Local Network Game Transfers
+  };
+}

shared/modules/gnome/default.nix

@@ -0,0 +1,29 @@
+{ pkgs, ... }:
+
+{
+  imports = [
+    ./nautilus.nix
+  ];
+
+  environment.systemPackages = with pkgs; [
+    # adw-gtk3
+    glib
+    adwaita-icon-theme
+    gnomeExtensions.appindicator
+    # gnome-extension-manager
+    # loupe
+    gnome-calculator
+    gnome-disk-utility
+    gnome-clocks
+    papers # PDFReader
+    pdfarranger
+  ];
+
+  programs.dconf.enable = true; # Required for some gnome applications
+
+  services = {
+    gnome.gnome-keyring.enable = true;
+    gvfs.enable = true; # Gnome Virtual File-system. Required for various things in nautilus
+    udev.packages = with pkgs; [ gnome-settings-daemon ];
+  };
+}

shared/modules/gnome/nautilus.nix

@@ -0,0 +1,13 @@
+{ pkgs, common, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    nautilus
+    ffmpegthumbnailer # Thumbnails
+  ];
+
+  programs.nautilus-open-any-terminal = {
+    enable = true;
+    terminal = common.default.terminal;
+  };
+}

shared/modules/hardware/audio.nix

@@ -0,0 +1,33 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    gst_all_1.gstreamer
+    gst_all_1.gst-plugins-base
+    gst_all_1.gst-plugins-good
+    gst_all_1.gst-plugins-bad
+
+    wireplumber
+    playerctl # Interaction with audioplayers and browsers
+    pavucontrol # GUI
+    spotify
+  ];
+
+  hardware.pulseaudio.enable = false; # Will be moved to services in 25.05
+
+  security.rtkit.enable = true; # Enable RealtimeKit for audio purposes
+
+  services = {
+    pipewire = {
+      enable = true;
+      alsa = {
+        enable = true;
+        support32Bit = true;
+      };
+      pulse.enable = true;
+      # Uncomment the following line if you want to use JACK applications
+      # jack.enable = true;
+    };
+    # pulseaudio.enable = false; # TODO uncommenct at 25.05
+  };
+}

shared/modules/hardware/default.nix

@@ -0,0 +1,7 @@
+{
+  imports = [
+    ./audio.nix
+    ./graphics
+    ./keyboard.nix
+  ];
+}

shared/modules/hardware/graphics/default.nix

@@ -0,0 +1,8 @@
+{
+  imports = [
+    ./nvidia.nix
+  ];
+
+  # Enable OpenGL
+  hardware.graphics.enable = true;
+}

shared/modules/hardware/graphics/nvidia.nix

@@ -0,0 +1,33 @@
+{
+  pkgs,
+  lib,
+  systemConfig,
+  ...
+}:
+
+lib.mkIf systemConfig.nvidia.enable {
+  boot.kernelParams = [ "nvidia.NVreg_PreserveVideoMemoryAllocations=1" ];
+
+  # For hardware acceleration
+  environment.sessionVariables.LIBVA_DRIVER_NAME = "nvidia";
+
+  hardware = {
+    graphics.extraPackages = with pkgs; [
+      # Used for hardware-acceleration
+      nvidia-vaapi-driver
+    ];
+    nvidia = {
+      # Required
+      modesetting.enable = true;
+      # Use closed-source drivers
+      open = false;
+      # Enable the Nvidia settings menu
+      nvidiaSettings = true;
+      # Enable nvidia-suspend.service, nvidia-hibernate.service and nvidia-resume.service
+      powerManagement.enable = true;
+    };
+  };
+
+  # Load Nvidia driver for Xorg and Wayland
+  services.xserver.videoDrivers = [ "nvidia" ];
+}

shared/modules/hardware/keyboard.nix

@@ -0,0 +1,11 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    via
+  ];
+
+  hardware.keyboard.qmk.enable = true;
+
+  services.udev.packages = with pkgs; [ via ];
+}

shared/modules/hyprland/default.nix

@@ -0,0 +1,24 @@
+# System configurations for Hyprland. For home configs, see ./shared/home-manager/hyprland
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    xdg-desktop-portal-hyprland
+    hyprpolkitagent # Auth deamon providing modals for password auth
+    hyprshot # Screenshots
+    unstable.hyprsysteminfo
+    unstable.hyprland-qtutils
+    unstable.hyprland-qt-support
+  ];
+
+  programs = {
+    hyprland = {
+      enable = true;
+      xwayland.enable = true;
+      withUWSM = true;
+    };
+    hyprlock.enable = true; # Lock screen
+  };
+
+  services.hypridle.enable = true; # Lock when unused
+}

shared/modules/locale.nix

@@ -0,0 +1,36 @@
+{ common, ... }:
+let
+  utf-8 = "UTF-8";
+  en = "en_GB.${utf-8}";
+  nb = "nb_NO.${utf-8}";
+in
+{
+  # Configure console keymap
+  console.keyMap = "uk";
+
+  # Select internationalisation properties.
+  i18n = {
+    defaultLocale = en;
+    supportedLocales = [
+      "${en}/${utf-8}"
+      "${nb}/${utf-8}"
+    ];
+    extraLocaleSettings = {
+      LC_ADDRESS = nb;
+      LC_IDENTIFICATION = nb;
+      LC_MEASUREMENT = nb;
+      LC_MONETARY = nb;
+      LC_NAME = nb;
+      LC_NUMERIC = nb;
+      LC_PAPER = nb;
+      LC_TELEPHONE = nb;
+      LC_TIME = nb;
+    };
+  };
+
+  # Configure keymaps
+  services.xserver.xkb = common.keymaps;
+
+  # Set your time zone.
+  time.timeZone = "Europe/Oslo";
+}

shared/modules/networking.nix

@@ -0,0 +1,22 @@
+{ systemConfig, ... }:
+
+{
+  networking = {
+    networkmanager.enable = true;
+    hostName = systemConfig.hostName;
+    # wireless.enable = true;  # Enables wireless support via wpa_supplicant.
+  };
+
+  # Configure network proxy if necessary
+  # networking.proxy.default = "http://user:password@proxy:port/";
+  # networking.proxy.noProxy = "127.0.0.1,localhost,internal.domain";
+  # Open ports in the firewall.
+  # networking.firewall.allowedTCPPorts = [ ... ];
+  # networking.firewall.allowedUDPPorts = [ ... ];
+  # Or disable the firewall altogether.
+  # networking.firewall.enable = false;
+
+  programs.ssh.enableAskPassword = false;
+
+  services.tailscale.enable = true;
+}

shared/modules/nix-helper.nix

@@ -0,0 +1,14 @@
+# Nix-Helper: github.com/viperML/nh
+{ common, ... }:
+
+{
+  programs.nh = {
+    enable = true;
+    flake = common.root;
+    clean = {
+      enable = true;
+      dates = "weekly";
+      extraArgs = "--keep-since 30d";
+    };
+  };
+}

shared/modules/qt.nix

@@ -0,0 +1,17 @@
+{ pkgs, ... }:
+
+{
+  environment = {
+    sessionVariables = {
+      QT_QPA_PLATFORMTHEME = "qt6ct";
+      QT_QPA_PLATFORM = "wayland"; # Enable Wayland for QT
+    };
+    systemPackages = with pkgs.kdePackages; [
+      qtwayland
+      qtsvg
+      qt6ct
+    ];
+  };
+
+  qt.enable = true;
+}

shared/modules/sddm.nix

@@ -0,0 +1,22 @@
+{ pkgs, theme, ... }:
+let
+  flavor = theme.flavor;
+in
+{
+  environment.systemPackages = with pkgs; [
+    (catppuccin-sddm.override {
+      flavor = flavor;
+      font = theme.nerdFont;
+      fontSize = "9";
+      background = builtins.toString ../assets/catppuccin_high.png;
+      loginBackground = true;
+    })
+  ];
+
+  services.displayManager.sddm = {
+    enable = true;
+    theme = "catppuccin-${flavor}";
+    wayland.enable = true;
+    package = pkgs.kdePackages.sddm;
+  };
+}

shared/modules/security.nix

@@ -0,0 +1,31 @@
+{ pkgs, ... }:
+
+{
+  environment.systemPackages = with pkgs; [
+    gnupg
+    yubioath-flutter
+  ];
+
+  programs.gnupg.agent.enable = true;
+
+  security = {
+    pam = {
+      services = {
+        login.u2fAuth = false; # U2F and password
+        sudo.u2fAuth = true; # U2F or password
+      };
+      u2f = {
+        enable = true;
+        settings = {
+          cue = true; # Prompt: Please touch the device
+          interactive = false; # Prompt: Insert your U2F device, then press ENTER.
+        };
+      };
+    };
+  };
+
+  services = {
+    pcscd.enable = true; # Required for Yubikey
+    udev.packages = with pkgs; [ yubikey-personalization ];
+  };
+}

shared/modules/shell.nix

@@ -0,0 +1,19 @@
+# For Fish dotfiles, see: /home-manager/fish.nix
+{ pkgs, ... }:
+
+{
+  programs = {
+    bash = {
+      # Starts the OS using Bash, then starts fish if it's not running
+      interactiveShellInit = ''
+        if [[ $(${pkgs.procps}/bin/ps --no-header --pid=$PPID --format=comm) != "fish" && -z ''${BASH_EXECUTION_STRING} ]]
+        then
+          shopt -q login_shell && LOGIN_OPTION='--login' || LOGIN_OPTION=""
+          exec ${pkgs.fish}/bin/fish $LOGIN_OPTION
+        fi
+      '';
+    };
+
+    fish.enable = true;
+  };
+}